(* Mathematica notebook to verify the van der Corput explicit bound *)

Clear[t0,r0,t,r,W,R0,λ,T,WW,α,β,ρ,A]
t0=9.3*10^7;
r0=5;
η0=(75/64)^(2/3);

(* formula for n1(t) *)
n1[t_]:=Floor[Sqrt[t/(2Pi)]]

(* formula for K *)
K[t_]:=Ceiling[t^(1/3)]

(* formula for R *)
R[t_] :=Floor[n1[t]/K[t]]

(* Bound for R_0(t) *)
Rem[t_]:=1.48t^(-1/4)+0.127t^(-3/4);

(* Bound first CalI(r,t) *)
CalI[r_,t_]:=2Sum[1/Sqrt[n],{n,1,Ceiling[r t^(1/3)]-1}]-4Sqrt[Ceiling[r t^(1/3)]-1]

(* Bound for smallest R *)
R0[t_]=Ceiling[N[(Sqrt[t/(2Pi)]-1)/(t^(1/3)+1)-1]];

(* Lower bound for W *)
W[r_]:=Pi(r+1)^3

(* formula for rho *)
ρ[R_,t_]:=(1+1/R)(1+1/t^(1/3))

(* Bound for λ *)
λ[r_]:=(r+1)^3/r^3

(* Bound for α *)
α[η_,W_,λ_]:=1/η+λ((64/75)Sqrt[η+1/W^(1/3)]+η/W^(1/3)+1/W^(2/3))

(* Bound for β *)
β[η_,W_]:=(64/15)(1/Sqrt[η])+3/W^(1/3)

(* Coeff of S bound *)

CoeffS = Sqrt[α[η0,W[r0],λ[r0]]+ η0 α[η0,W[r0],λ[r0]]ρ[R0[t0],t0]/(Sqrt[2]Pi^(1/6)t0^(1/6))+β[η0,W[r0]]ρ[R0[t0],t0]^2/(2Pi^(1/3))+η0 β[η0,W[r0]]ρ[R0[t0],t0]^3/(2^(3/2)Sqrt[Pi]t0^(1/6))];

S=(2T^(1/6)/(Pi^(1/6)))*CoeffS*((1/6)Log[T]-Log[Sqrt[2Pi](r0-1)]);

Expand[N[S+4Sqrt[r0]Sqrt[1+t0^(-1/3)]T^(1/6)+CalI[r0,t0]+Rem[t0]]]

MyBoundNew[T_]:=-2.884626766806946`+0.5743984045896529` (T^(1/6))+0.6058490462529491` (T^(1/6)) Log[T]
Trivial[t_]:=4t^(1/4)/(2Pi)^(1/4)-2.08

Clear[t,c]
Solve[{Trivial[t]-MyBoundNew[t]==0,t>0},t,Reals]

Solve[Trivial[t0]-c t0^(1/6)Log[t0]==0,c]

NB[t_]:= 0.63 t^(1/6)Log[t]

Solve[{NB[t]-Trivial[t]==0,t>100},t,Reals]
Trivial[200.]
NB[200.]

Solve[{NB[t]-MyBoundNew[t]==0,t>0},t,Reals]
MyBoundNew[t0]
NB[t0]

LogLinearPlot[Trivial[t]-NB[t],{t,10^2,10^8},GridLines->{{},{0}}]
LogLinearPlot[NB[t]-MyBoundNew[t],{t,t0,10^20},GridLines->{{},{0}}]